//subdUVprep.ls
//
//march 27 2010
//clinton reese
//www.clintons3d.com
//
//purpose to prepare subpatched uv for eps export
//usage:
//      1. be sure uv interpolation is set to subpatch
//      2. run this script
//
@version 2.1
@warnings
@script modeler
@name subdUVprep

main
{
    //mesh should already be subd
    //uv interpolation must be set to subpatch before running

    selmode(USER);
    //copy to a new free layer
    workLayer = lyrempty();
    copy();
    lyrsetfg(workLayer[1]);
    paste();
    selmode(GLOBAL);

    //get number of polygons
    editbegin();
        numpolyarr = polycount();
        numpoly = numpolyarr[1];//1=all polygons
    editend();

    moninit(numpoly, "Assign surface to each face...");

    //assign a new surface to each face
    selmode(USER);
    for(i=1;i<=numpoly;i++)
    {
        if(monstep()) return;

        selpolygon(SET, POLYNDX, i);
        surfname = "subdconv_" + i;
        changesurface(surfname);
        selpolygon(CLEAR);
    }

    monend();
    moninit(numpoly, "Merging faces...");

    //freeze mesh
    freezecurves();//manual says curves but works on subd faces
    //for each surface merge polygons
    for(i=1;i<=numpoly;i++)
    {
        if(monstep()) return;

        surfname = "subdconv_" + i;
        selpolygon(SET, SURFACE, surfname);
        mergepols();
        selpolygon(CLEAR);
    }
    //remove stray vertices
    selpoint(SET,NPEQ,0);
    delete();

    monend();
}