//morphSequencer.ls
//february 26 2010
//clinton reese
//www.clintons3d.com
//
//take a series of morphs and create a sequencial morph sequence by creating intermediate morphs and 
//adding them at different morph values to the last morph in the sequence
//
// type number of morphs to use - the first morphs listed will be used
// type a prefix name for the new intermediate morphs
// choose morph order from the drop down lists
// choose whether interpolation is linear or not(no effect on the last morph)
// press ok to generate the intermediate morphs and the expressions to drive them
// copy the expressions to a temp location
// in layout: copy the expressions to the corresponding morphs
// final result: intermediate morphs driven by the final/last morph values to create sequential morph action
//
// note: non-linear interp not so good, default linear
//
//Preprocessor Compiler Directives.
// sample expression for 2 morph sequence, add together and apply to intermediate morph
//range([rectangle.MorphGroup.second],0.000,0.500) * mapRange([rectangle.MorphGroup.second],0.000,0.500,0.000,1.000)
//range([rectangle.MorphGroup.second],0.501,1.00) * mapRange([rectangle.MorphGroup.second],0.500,1.000,1.000,0.000)
//
@script modeler
@name "morphSequencer"
@version 2.3
main
{
    //Create a VMap Object Agent. from all the morph maps
    allvmapObj = VMap(VMMORPH);
    
    //If there are no maps, notify the user.
    if(allvmapObj == nil)
        error("No morph maps in the mesh!");
        
    /* using a while statement, if there s a VMap value, and
    its type is VMMORPH add the names to the variable.
    This handles multiple VMaps in the object. */
    nummorphs = 0;
    while(allvmapObj && allvmapObj.type == VMMORPH)
    {
        vmapnames += allvmapObj.name;
        nummorphs = nummorphs + 1;
        //Use the .next() method to go to the next VMap.
        allvmapObj = allvmapObj.next();
    }
    if(nummorphs < 2)
        error("Not enough morphs to sequence.");
    
    /* Interface to get morph order.*/
    reqbegin("Sequence Morph");
        morphcount = ctlinteger("Number of morphs to use",nummorphs);
        ctlposition(morphcount,12,10);
        morphprefixctl = ctlstring("Morph Prefix", "seqmorph");
        ctlposition(morphprefixctl,12,40);
        for(y=1;y<=nummorphs;y++)
        {
            mtext = "morph " + y;
            mypopup[y] = ctlpopup(mtext, y, vmapnames);//also add checkboxes for non-linear interpolation default
            vpos = (y + 1) * 30 + 10;
            ctlposition(mypopup[y],12,vpos);
            mycheckctl[y] = ctlcheckbox("non-linear",false);
            ctlposition(mycheckctl[y],220,vpos);
        }
        return if !reqpost();
        
        //save inputs
        nummorphs = getvalue(morphcount);
        morphprefix = getvalue(morphprefixctl);
        for(y=1;y<=nummorphs;y++)
        {
            theval = getvalue(mypopup[y]);
            newvmapnames[y] = vmapnames[theval];
            mycheck[y] = getvalue(mycheckctl[y]);
        }
    reqend();
    
    // do sequence here
    
    //check that user requested enough morphs
    if(nummorphs < 2) error("Not enough morphs to sequence");
    
    //save the mesh name for the script text output
    obj = Mesh(0);
    objname = obj.name;

    lastvmapObj = VMap(newvmapnames[nummorphs]);//last morph - driver of the script text
    lastmorphname = lastvmapObj.name;
    
    selmode(USER);
    morphstep = 1/nummorphs;
    editbegin();
        for(i=1;i<nummorphs;i++)
        {
            scaler = morphstep * i;
            
            //save script text for each morph
            //each sequence morph will be driven by the last morph percentage
            startrange = morphstep * (i - 1);
            endrange = scaler;
            rangetext = format("$1,$2",startrange,endrange);

            thetarget = "[" + objname + ".MorphGroup." + lastmorphname + "]";

            //choose sin interpolation or linear for first half
            if(mycheck[i])
                scripttext1 = "range(" + thetarget + "," + rangetext + ") * sin(3.14159/2 * mapRange(" + thetarget + "," + rangetext + ",0.000,1.000))";
            else
                scripttext1 = "range(" + thetarget + "," + rangetext + ") * mapRange(" + thetarget + "," + rangetext + ",0.000,1.000)";
            
            startrange=endrange + 0.001;
            endrange = morphstep * ( i + 1);
            rangetext = format("$1,$2",startrange,endrange);

            //choose sin interpolation or linear for second half(same as first half)
            if(mycheck[i])
                scripttext2 = "range(" + thetarget + "," + rangetext + ") * sin(3.14159/2 * mapRange(" + thetarget + "," + rangetext + ",1.000,0.000))";
            else
                scripttext2 = "range(" + thetarget + "," + rangetext + ") * mapRange(" + thetarget + "," + rangetext + ",1.000,0.000)";
                
            thescript[i] = scripttext1 + " + " + scripttext2;
            
            newName = morphprefix + i;
            newVmap = VMap(VMMORPH,newName,3); // create a Relative morphmap with 3 elements, x,y,z
            curvmapObj = VMap(newvmapnames[i]);//current morph
            
            //Get the number of points selected.
            pntCnt = pointcount();
            //Setup for-loop to cycle through selected pts.
            for(pnt = 1; pnt <= pntCnt; pnt++)
            {
                //read points for lastmorph with scaler mult xyz
                if(lastvmapObj.isMapped(points[pnt]))
                {
                    //If so, get the VMap value.
                    lastvalues = lastvmapObj.getValue(points[pnt]);
                    //mult by scaler
                    for(j=1;j<=3;j++)
                        lastvalues[j] *= scaler;
                }
                else
                {
                    //set to 0,0,0
                    lastvalues[1]=0; lastvalues[2]=0; lastvalues[3]=0;
                }
                //read points for current morph and get difference morph point value
                if(curvmapObj.isMapped(points[pnt]))
                {
                    //If so, get the VMap value.
                    curvalues = curvmapObj.getValue(points[pnt]);
                    //get difference and store new morph point
                    for(j=1;j<=3;j++)
                        curvalues[j] = curvalues[j] - lastvalues[j];
                    newVmap.setValue(points[pnt], curvalues);
                }
            }
        }
    editend();
    reqbegin("Sequence Morph Expressions");
        //will have one expression for each string control
        for(i=1;i<nummorphs;i++)
        {
            vpos = (i - 1) * 40 + 10;
            newName = morphprefix + i;
            mylabel = newName + " Expr.";
            c[i] = ctlstring(mylabel, thescript[i]);
            ctlposition(c[i],12,vpos,500);
            s[i] = ctlsep(12,20);
            ctlposition(s[i],450,vpos+25);
        }
        return if !reqpost();
    reqend();
}